Merge e4355cbbda into 1d793c485e

app/build.gradle

@@ -1,116 +0,0 @@
-apply plugin: 'com.android.application'
-apply plugin: 'kotlin-android'
-apply plugin: 'kotlin-kapt'
-apply plugin: 'kotlinx-serialization'
-
-android {
-    dataBinding {
-        enabled = true
-    }
-
-    packaging {
-        resources.excludes.addAll(
-                [
-                        "META-INF/LICENSE.md",
-                        "META-INF/NOTICE.md",
-                        "META-INF/LICENSE-notice.md"
-                ]
-        )
-    }
-
-    defaultConfig {
-        applicationId "de.jrpie.android.launcher"
-        minSdkVersion 21
-        targetSdkVersion 35
-        compileSdk 35
-        versionCode 47
-        versionName "0.2.2"
-
-        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
-    }
-    compileOptions {
-        sourceCompatibility JavaVersion.VERSION_17
-        targetCompatibility JavaVersion.VERSION_17
-    }
-    kotlinOptions {
-        jvmTarget = '17'
-    }
-
-    buildFeatures {
-        viewBinding true
-    }
-
-
-    buildTypes {
-        release {
-            minifyEnabled true
-            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
-        }
-        debug {
-            applicationIdSuffix = ".debug"
-            versionNameSuffix = "-debug"
-        }
-    }
-
-    flavorDimensions += "distribution"
-
-    productFlavors {
-        create("default") {
-            dimension = "distribution"
-            getIsDefault().set(true)
-            buildConfigField "boolean", "USE_ACCESSIBILITY_SERVICE", "true"
-        }
-        create("accrescent") {
-            dimension = "distribution"
-            applicationIdSuffix = ".accrescent"
-            versionNameSuffix = "+accrescent"
-            buildConfigField "boolean", "USE_ACCESSIBILITY_SERVICE", "false"
-        }
-    }
-
-    sourceSets {
-        accrescent {
-            manifest.srcFile 'src/accrescent/AndroidManifest.xml'
-        }
-    }
-
-    namespace 'de.jrpie.android.launcher'
-    buildFeatures {
-        buildConfig true
-    }
-
-    dependenciesInfo {
-        // Disables dependency metadata when building APKs.
-        includeInApk = false
-        // Disables dependency metadata when building Android App Bundles.
-        includeInBundle = false
-    }
-    lint {
-        abortOnError false
-    }
-
-
-}
-
-dependencies {
-    implementation fileTree(dir: 'libs', include: ['*.jar'])
-    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk7:$kotlin_version"
-    implementation 'androidx.activity:activity-ktx:1.8.0'
-    implementation 'androidx.appcompat:appcompat:1.7.0'
-    implementation 'androidx.core:core-ktx:1.15.0'
-    implementation 'androidx.constraintlayout:constraintlayout:2.2.0'
-    implementation 'androidx.gridlayout:gridlayout:1.0.0'
-    implementation 'androidx.palette:palette-ktx:1.0.0'
-    implementation 'androidx.recyclerview:recyclerview:1.4.0'
-    implementation 'androidx.preference:preference-ktx:1.2.1'
-    implementation 'com.google.android.material:material:1.12.0'
-    implementation("org.jetbrains.kotlinx:kotlinx-serialization-json:1.7.3")
-    implementation "eu.jonahbauer:android-preference-annotations:1.1.2"
-    implementation 'androidx.activity:activity:1.10.1'
-    annotationProcessor "eu.jonahbauer:android-preference-annotations:1.1.2"
-    annotationProcessor "com.android.databinding:compiler:$android_plugin_version"
-    testImplementation 'junit:junit:4.13.2'
-    androidTestImplementation 'androidx.test.ext:junit:1.2.1'
-    androidTestImplementation 'androidx.test.espresso:espresso-core:3.6.1'
-}
-

app/build.gradle.kts

@@ -0,0 +1,101 @@
+plugins {
+    alias(libs.plugins.android.application)
+    alias(libs.plugins.kotlin.android)
+    alias(libs.plugins.kotlin.kapt)
+    alias(libs.plugins.kotlin.serialization)
+}
+
+android {
+    namespace = "de.jrpie.android.launcher"
+    compileSdk = 35
+
+    defaultConfig {
+        applicationId = "de.jrpie.android.launcher"
+        minSdk = 21
+        targetSdk = 35
+        versionCode = 47
+        versionName = "0.2.2"
+
+        testInstrumentationRunner = "androidx.test.runner.AndroidJUnitRunner"
+    }
+
+    buildTypes {
+        release {
+            isMinifyEnabled = true
+            proguardFiles(
+                getDefaultProguardFile("proguard-android-optimize.txt"),
+                "proguard-rules.pro"
+            )
+        }
+        debug {
+            applicationIdSuffix = ".debug"
+            versionNameSuffix = "-debug"
+        }
+    }
+
+    val distributionDimension = "distribution"
+    
+    flavorDimensions += distributionDimension
+
+    productFlavors {
+        create("default") {
+            dimension = distributionDimension
+            isDefault = true
+            buildConfigField("boolean", "USE_ACCESSIBILITY_SERVICE", "true")
+        }
+        create("accrescent") {
+            dimension = distributionDimension
+            applicationIdSuffix = ".accrescent"
+            versionNameSuffix = "+accrescent"
+            buildConfigField("boolean", "USE_ACCESSIBILITY_SERVICE", "false")
+        }
+    }
+
+    sourceSets {
+        this.getByName("accrescent") {
+            this.java.srcDir("src/accrescent")
+        }
+    }
+
+    compileOptions {
+        sourceCompatibility = JavaVersion.VERSION_17
+        targetCompatibility = JavaVersion.VERSION_17
+    }
+    kotlinOptions {
+        jvmTarget = "17"
+    }
+    buildFeatures {
+        buildConfig = true
+        compose = false
+        dataBinding = true
+        viewBinding = true
+    }
+
+    dependenciesInfo {
+        includeInApk = false
+        includeInBundle = false
+    }
+
+    lint {
+        abortOnError = false
+    }
+}
+
+dependencies {
+    implementation(libs.androidx.activity)
+    implementation(libs.androidx.activity.ktx)
+    implementation(libs.androidx.appcompat)
+    implementation(libs.androidx.constraintlayout)
+    implementation(libs.androidx.core.ktx)
+    implementation(libs.androidx.gridlayout)
+    implementation(libs.androidx.palette.ktx)
+    implementation(libs.androidx.preference.ktx)
+    implementation(libs.androidx.recyclerview)
+    implementation(libs.google.material)
+    implementation(libs.kotlinx.serialization.json)
+    implementation(libs.jonahbauer.android.preference.annotations)
+    kapt(libs.jonahbauer.android.preference.annotations)
+    testImplementation(libs.junit)
+    androidTestImplementation(libs.androidx.espresso.core)
+    androidTestImplementation(libs.androidx.test.ext.junit)
+}

app/proguard-rules.pro

@@ -2,7 +2,7 @@
 -dontobfuscate
 -dontoptimize
 # You can control the set of applied configuration files using the
-# proguardFiles setting in build.gradle.
+# proguardFiles setting in build.gradle.kts.
 #
 # For more details, see
 #   http://developer.android.com/guide/developing/tools/proguard.html

app/src/main/java/de/jrpie/android/launcher/ui/settings/meta/SettingsFragmentMeta.kt

@@ -32,7 +32,8 @@ class SettingsFragmentMeta : Fragment(), UIObject {
 
     private lateinit var binding: SettingsMetaBinding
     override fun onCreateView(
-        inflater: LayoutInflater, container: ViewGroup?,
+        inflater: LayoutInflater,
+        container: ViewGroup?,
         savedInstanceState: Bundle?
     ): View {
         binding = SettingsMetaBinding.inflate(inflater, container, false)